¿Tiene preguntas? Tenemos respuestas.

Búsqueda

  1. MindBridge: Spanish (Spain)
  2. Empezar
  3. Importe archivos
  4. Formateo de datos

Guía de Formateo de Datos: Desagrupación simple de múltiples columnas, rellenar números de cuenta en blanco (ejemplo común de QuickBooks)

  • Actualización

Resumen

Aprenda cómo desagrupar un archivo de datos rellenando múltiples columnas para producir un archivo que sea compatible con MindBridge. Este es un problema común en muchas exportaciones de datos tomadas de sistemas de contabilidad como QuickBooks. 

Este método puede incluso ser utilizado si no todas las columnas tienen un valor en la primera fila del grupo, y para rellenar números de cuenta en blanco cuando la descripción de la cuenta está presente pero el número de cuenta no lo está.

Nota: Si es posible, primero intente configurar un conector directo o haga que su cliente se conecte para extraer los datos directamente en MindBridge, o siga estas instrucciones para exportar desde QuickBooks Online o QuickBooks Desktop para evitar la necesidad de desagrupar los datos. Esta guía está destinada a situaciones en las que es imposible configurar un conector directo u obtener una mejor exportación.

Resolución

Considere el siguiente extracto de un archivo de libro mayor de QuickBooks:

mceclip1.png

Los problemas

  1. Este archivo está agrupado por transacción; Fecha, Tipo de transacción, No., y Nombre están presentes solo en la primera fila en el grupo de transacciones y necesitan ser arrastrados hacia abajo.
  2. El No. de cuenta no siempre está presente (ver por ejemplo las filas 8, 13, 17, 25), pero la Cuenta sí. La Cuenta puede ser mapeada al ID de cuenta, pero el No. de cuenta no puede a menos que se rellenen los espacios en blanco.
  3. Hay filas de subtotal de transacción innecesarias (9, 14, 19, 26)

La solución (formateo necesario)

  1. Arrastre Fecha, Tipo de transacción, No., y Nombre hacia abajo a cada fila de transacción
  2. Rellene el No. de cuenta en blanco con el valor en Cuenta
  3. Excluya filas de total/subtotal/extráneas en blanco (9, 14, 19, 26) y filas extráneas (filas 1-4) por encima de la fila de encabezado (fila 5)

Pondremos las columnas revisadas al final del archivo.

  • Fecha y Tipo de transacción siempre están presentes en la primera fila del grupo de transacciones, pero No. y Nombre a veces están en blanco para un grupo. Vea los grupos de transacciones 3 y 4 que comienzan en las filas 16 y 21.
  • Nuestra lógica será tomar el valor de la columna original si estamos en la primera fila de la transacción, o el valor anterior que encontramos si no estamos en la primera fila de la transacción.

Fecha revisada: Celda L6 y siguientes

mceclip3.png

=IF(LEN($B6)>0,IF(LEN(B6)>0,B6,""),L5)
  • LEN($B6)>0
    prueba si hay un valor en la columna B probando si la longitud es mayor que 0. Dado que, como observamos, la Fecha siempre está presente en la primera fila del grupo de transacciones, esto sirve como nuestra verificación de si estamos en la primera fila de la transacción. Ponemos $ delante de la B para facilitar la copia de la fórmula al resto de las columnas para arrastrar hacia abajo (Tipo de transacción, No., Nombre), ya que siempre estaremos verificando la presencia de la Fecha para comprobar si estamos en la primera fila de la transacción
  • IF(LEN(B6)>0,B6,"")
    devuelve la fecha si está presente, "" (cadena vacía) si no lo está. Esto se puede simplificar simplemente a B6 para la columna Fecha porque la Fecha siempre está presente en la primera fila del grupo de transacciones, pero esta lógica se usa para poder copiar y pegar las mismas fórmulas para No. y Nombre, que, como se mencionó anteriormente, no siempre están presentes. Debido a que Excel mostrará 0 en lugar de vacío cuando se hace referencia a una celda vacía, tenemos que decirle que devuelva "" para que muestre una celda vacía.

Nota: Las fórmulas anteriores que verifican la cadena vacía asumen que las celdas que parecen vacías están realmente vacías en Excel. Si estas celdas que parecen vacías en realidad contienen espacios, espacios no separables o datos fantasma, sustituya lo siguiente por todas las instancias de B6 dentro de la función LEN():

TRIM(CLEAN(SUBSTITUTE(B6,CHAR(160)," ")))
  • El TRIM() elimina espacios
  • CHAR(160) indica el carácter de espacio no separable, y la fórmula SUBSTITUTE() a su alrededor elimina los caracteres de espacio no separable (nota: en un Mac, use CHAR(202) en lugar de CHAR(160))

Entonces, la fórmula final sería:

=IF(LEN(TRIM(CLEAN(SUBSTITUTE($B6,CHAR(160)," "))))>0,IF(LEN(TRIM(CLEAN(SUBSTITUTE(B6,CHAR(160)," "))))>0,B6,""),L5)

Tipo de transacción, No., Nombre revisados

Copie y pegue y arrastre hacia abajo la fórmula encontrada para la Fecha revisada.

mceclip4.png

Las fórmulas en las celdas M6, N6 y O6 deberían ser las siguientes:

=IF(LEN($B6)>0,IF(LEN(C6)>0,C6,""),M5)
=IF(LEN($B6)>0,IF(LEN(D6)>0,D6,""),N5)
=IF(LEN($B6)>0,IF(LEN(F6)>0,F6,""),O5)

No. de cuenta revisado

Nuestra lógica para rellenar los espacios en blanco para el No. de cuenta en la columna P será tomar el No. de cuenta original de la columna H si está presente (la longitud es mayor que 0), Cuenta de la columna I si no lo está (la longitud no es mayor que 0):

mceclip5.png

=IF(LEN(H6)>0,H6,I6)

Filtro para mantener solo filas de transacción

Observamos que cada fila de transacción en el archivo original tiene una Cuenta. Así que con los filtros activados, filtre los espacios en blanco de la columna I (Cuenta):

mceclip6.png

Copiar y pegar valores en un nuevo libro de trabajo

Luego seleccione la fila de encabezado y las filas de transacción seleccionadas (es decir, la fila 5 en adelante en la vista filtrada - puede comenzar en la celda B5, presionar Ctrl-Shift-End para llegar al final del archivo y ajustar la posición según sea necesario), luego copie, luego pegue valores especiales en un nuevo libro de trabajo.

¿Algo más en mente? Chatee con nosotros o envíe una solicitud para obtener más ayuda.

Artículos relacionados

¿Fue útil este artículo?